Stages of Latent Transition Analysis

Latent Transition Analysis requires analyses that are conducted in different stages, corresponding to the goals of identifying the optimal person-centred measurement model at each time point or measurement occasion, followed by investigation of structural relationships between the latent variables identified, and between these and covariates or predictors. The stages described here are reported with more details in Ryoo et al. (2018) and Perra (2020).

**Stage 1: Decide the Number of Latent Classes at Each Time Point**

The first stage involves running separate Latent Class Analyses (LCA) at each time point of data collection to identify the optimal person-centred models that adequately describe inter-personal variation in the behaviour patterns observed.

Since we should run LCA, we will have to run and compare models where we increase the number of latent classes from 1 (i.e. a model with no inter-personal variability) to *n* (the number of classes we can estimate is constrained by model identification issues). It is important that the LCA models estimated are stable, i.e. the best Log-Likelihood is replicated a sufficient number of times (see my resources on LCA for more details).

There are different statistics that should be used to determine the optimal LCA solution. These include:

* Fit statistics: Pearson *χ2* and Likelihood Ratio *χ2* Comparisons;
* Tests comparing models with n and n-1 class: e.g. Bootstrap Likelihood-Ratio Test;
* Information Criteria: e.g. Bayesian Information Criterion (BIC);
* The extent of large bivariate residuals associated with different moels;
* Entropy: Index of the precision of individuals’ categorisation into classes (range 0 to 1).

In most cases these statistics will point to different solutions. It may therefore be useful to consider a pool of measurement models for investigation in the following stages of LTA.

**Stage 2: Test Measurement Invariance Across Time Points**

If the measurement models identified at each time point are providing solutions that look very different, then measurement invariance would be clearly unwarranted. However, if the solutions from Stage 1 provide latent classes that look similar across time, it is worthwhile to test measurement invariance.

If the solutions suggest that the same number of latent classes emerge at each time point, and these latent classes look similar, we may test if *full measurement invariance* is warranted. A model with full measurement invariance offers the advantage of simplifying results interpretation, since the latent classes estimated at each time point will have the same meaning. To define a model with full measurement invariance using Mplus, see the file *1.0 Introduction to LTA using Mplus* provided with these resources.

When testing measurement model parameters, it is advisable to avoid imposing a structure to the associations between classes, i.e. avoid regressing latent classes at one time point on latent classes at the previous time point (see Perra, 2020).

A model with full measurement invariance is nested within one where measurement parameters are freely estimated. Therefore, the fit of the two models can be compared using a Likelihood Ratio Test (LRT). However, by default, Mplus uses the MLR estimator: the use of this estimator requires a correction when we calculate the LRT between two models.

The formulas for the LRT when using a MLR estimator are:

LR test = ; ; Degrees of freedom = ;

Where:

L0  = Log-Likelihood of the null model (that with equality constraints);

L1  = Log-Likelihood of the model without the added constraints;

c0  = Scaling correction factor of the null model (that with equality constraints);

c1  = Scaling correction factor of the model without the added constraints;

p0  = Free parameters in the null model (that with equality constraints);

p1  = Free parameters in the model without the added constraints;

**Stage 3: Estimate Measurement Model Parameters and Modal Class Assignment**

Once we have selected the measurement models at each time point and their characteristics (i.e. measurement invariance), we can use the Three-Step Approach to assign each participant to their most likely latent class at each time point, as well as estimate the log-odds that represent mis-classification errors in these assignments. This information will be used to fix the measurement model in the following stages of LTA, while allowing to control for uncertainty in latent class affiliation. See the file *1.1 Three-Step Approach\_OliverPerra\_IntroLTA* provided with these resources for details on the Three-Stage Approach and how to run it when measurement invariance is assumed or not.

**Stage 4: Impose Structural Relationships between Latent Classes across Time Points**

When we use the Three-Step Approach we will be working with fixed measurement models. Therefore, we can run models with different structural relationships between latent classes and covariates. Specification of these models will not affect the measurement model parameters.

Latent classes estimated at different time points are nominal variables, therefore the regressions between them will be *multinomial logistic regressions*. Mplus considers the last category of a nominal or categorical variables as the reference category by default.

Let’s take example 8.13 from the Mplus manual: I have tweaked this example to consider only two latent class variables, **c1** and **c2**, with 3 categories each, and then I modelled the regression of the **c2** classes on the **c1** classes:

USEVAR= u11-u15 u21-u25;

CATEGORICAL = u11-u15 u21-u25;

CLASSES = c1 (3) c2 (3);

ANALYSIS: TYPE = MIXTURE;

MODEL:

%OVERALL%

**c2 ON c1;**

[…]

The parameters that Mplus report are the logit “Means” or intercepts of the latent variables **c1** and **c2**, and the logits of the regressions of **c2** on **c1**, as shown below.

Two-Tailed

Estimate S.E. Est./S.E. P-Value

C2#1 ON

C1#1 1.377 0.323 4.263 0.000

C1#2 1.072 0.330 3.251 0.001

C2#2 ON

C1#1 0.578 0.581 0.995 0.320

C1#2 0.229 0.678 0.338 0.736

Means

C1#1 -0.259 0.248 -1.042 0.297

C1#2 -0.592 0.463 -1.279 0.201

C2#1 -0.377 0.238 -1.587 0.112

C2#2 -1.124 0.572 -1.965 0.049

Based on these parameters, we can estimate the probability of **c1** latent classes by transforming the logits in odds, and the odds in probabilities:

For example, the odds of being in category 1 of **c1** will be:

Odds c1#1 = exp (Logit c1#1) = exp(-0.259) = 0.772

and the odds of category 2 of latent class **c1** will be:

Odds c1#2= exp (Logit c1#2) = exp(-0.592) = 0.553

Using these, the probability of category 1 of latent class **c1** will be:

*p* (c1#1) = = = 0.332

While the probability of category 2 of latent class **c2** will be:

*p* (c1#2) = = = 0.238

Since the probabilities add up to 1, the probability of category 3 will be equal to 1 – (0.332+0.238).

Since I have modelled the regression of **c2** on **c1**, the prevalence of categories of latent variable **c2** will depend on the intercepts of **c2** and the slopes represented by the parameters “**c2#1 on c1#1”**, etc. The probabilities of transitions from categories of **c1** to categories of **c2** are calculated considering that, for example, the probability of being category 1 of **c2** given participants were in category 1 of **c1** is given by the sum of the intercept (**c2#1**) and the slope (**c2#1 ON c1#1**). If we put these parameters in a table to represent logits of transition probabilities this will look like this:

|  |  |  |  |
| --- | --- | --- | --- |
|  | c2#1 | c2#2 | c2#3 |
| c1#1 | c2#1 + (c2#1 ON c1#1) | c2#2 + (c2#2 ON c1#1) | 0 |
| c1#2 | c2#1 + (c2#1 ON c1#2) | c2#2 + (c2#2 ON c1#2) | 0 |
| c1#3 | c2#1 | c2#2 | 0 |

To calculate the odds of these transition probabilities, we exponentiate these parameters (see Mplus output reported above):

|  |  |  |  |
| --- | --- | --- | --- |
|  | c2#1 | c2#2 | c2#3 |
| c1#1 | exp( -0.377+1.377) | exp( -1.124+0.578) | exp(0) |
| c1#2 | exp(-0.377+1.072) | exp(-1.124+0.229) | exp(0) |
| c1#3 | exp(-0.377) | exp(-1.124) | exp(0) |

The results will provide the Odds that we can the use to calculate the transitions probabilities:

|  |  |  |  |
| --- | --- | --- | --- |
|  | c2#1 | c2#2 | c2#3 |
| c1#1 | 2.718 | 0.579 | 1 |
| c1#2 | 2.004 | 0.409 | 1 |
| c1#3 | 0.686 | 0.325 | 1 |

Using these odds, we can calculate that, for example, the probability of being in category 2 of latent class **c2** if someone was in category 1 of latent class **c1** is given by:

p (c2#1 | c1#1) =

Similarly, the probabilities of the other categories of **c2** given membership in category 1 of **c1** are given by:

p (c2#2 | c1#1) =

and

p (c2#3 | c1#1) =

I give this example to illustrate how Mplus parameters are related to the class probabilities, although Mplus reports these probabilities without carrying out these calculations. Understanding how these parameters relate to probabilities can also be useful when we want to impose or test constraints on probabilities. In fact, we can impose constraints on the model logits (c1#1, c1#2, c2#1 c2#2, c2#1 ON c1#1, …etc.) to ensure the probabilities of some categories or those of some transitions are constrained to pre-defined levels.

For example, if we assume that the classes represented progress in some ability from level 1 (less able) to level 3 (more able), we may be interested in testing a model where there is no “backsliding”, i.e., where we do not expect to observe respondents transitioning from “ability” to a “less able” class. By constraining the logits, we can affect the resulting probabilities.

However, Mplus facilitates the task of imposing constraints on class probabilities by using the probability parameterization rather than the default logit parameterization. In the **ANALYSIS:** command, you could instruct **PARAMETERIZATION=PROBABILITY**. In this case, the parameters of the model are the conditional probabilities of **c2** categories on **c1** categories. We can therefore constrain the probabilities of backsliding in this way:

USEVAR= u11-u15 u21-u25;

CATEGORICAL = u11-u15 u21-u25;

CLASSES = c1 (3) c2 (3);

ANALYSIS: TYPE = MIXTURE;

**PARAMETERIZATION=PROBABILITY;**

MODEL:

%OVERALL%

c2 ON c1;

**c2#1 ON c1#2@0;**

**c2#1 ON c1#3@0;**

**c2#2 ON c1#3@0;**

[…]

The last three lines (in bold) are constraining the probability of category 1 of **c2** given membership in category 2 of **c1** to be equal to 0, and so on. These constraints will produce a similar output:

A picture containing text, screenshot, font, receipt

Description automatically generated

which shows no probabilities of backsliding, e.g. moving from category 2 of **c1** to category 1 of **c2**, etc.

**Stage 5: Include Covariates**

At this stage covariates can be included in the LTA model to test the associations between these and latent classes. When including covariates, we are modelling *multinomial logistic regressions* between the latent classes and the covariates.

When we introduce a covariate, latent class membership at *time 1* will be affected by latent class membership at *time 0* as well as by the covariates. See Muthén and Asparouhov (2011) for a detailed illustration.

Latest additions to Mplus allow to extract transition probabilities for different values of the covariates: this is done by adding **Tech15** option to the **OUTPUT:** command. Once the output file is produced, select **Mplus🡪LTA Calculator** from the menu tab. This will open a dialog window that allows you to select the values of the covariates (e.g. an average value, or a specific numeric one) and will then produce calculations of the transition probabilities for that set of covariates values.

At this stage we might also be interested in testing moderation effects. Namely, we may hypothesise that the associations between latent categories between *time 0* and *time 1* may vary conditionally on some covariate (e.g. Socio-Economic Status).

Muthén and Asparouhov (2011) provide a more detailed description of different parameterizations of moderation effects and how parameters can be used to calculate probabilities. When using the Three-Step Approach, a simple straightforward way to add a moderation effect is to include the regression of the latent classes at *time point 1*  as parameters within each of the latent classes at *time point 0*. For example:

USEVAR= u11-u15 u21-u25 **male**;

CATEGORICAL = u11-u15 u21-u25;

CLASSES = c1 (3) c2 (3);

ANALYSIS: TYPE = MIXTURE;

MODEL:

%OVERALL%

c2 ON c1;

c1 ON male;

**Model c1:**

**%c1#1%**

**c2#1 ON male;**

**c2#2 ON male;**

[…]

**%c1#2%**

**c2#1 ON male;**

**c2#2 ON male;**

[…]

**%c1#3%**

**c2#1 ON male;**

**c2#2 ON male;**

The syntax above will estimate different parameters for the regression of **c2** classes that vary within classes of **c1**, effectively modelling an interaction term. Invoking **TECH15** in the **OUTPUT:** and then using **Mplus🡪 LTA Calculator** allows to inspect the transition probabilities for different value of the covariate.

**Stage 6: Include Distal Outcomes**

The Three-Step Approach also facilitates inclusion of effects over distal covariates. For example, if I wanted to test if respondents in different categories of latent variable **c2** displayed different average scores on a test, I would instruct Mplus to estimate the average values and the variances of the test within each category of **c2**:

USEVAR= u11-u15 u21-u25 **test**;

CATEGORICAL = u11-u15 u21-u25;

CLASSES = c1 (3) c2 (3);

ANALYSIS: TYPE = MIXTURE;

MODEL:

%OVERALL%

c2 ON c1;

Model c1:

[…]

**Model c2:**

**%c2#1%**

[…]

**[test] (t1);**

**test;**

**%c2#2%**

[…]

**[test] (t2);**

**test;**

**%c2#2%**

[…]

**[test] (t3);**

**test;**

By naming the average values of **test** in **c2#1**, **c2#2** and **c2#3** as (**t1**), (**t2**) and (**t3**) respectively, I can also invoke a Wald test to test null hypotheses on these parameters. If, for example, I wanted to test if the average test results for individuals in **c2#1** is not significantly different from that of individuals in **c2#3**, I would add these lines to the **MODEL:** command:

**MODEL TEST:**

**0=t1-t2;**

**References:**

Muthén, B., & Asparouhov, T. (2011). LTA in Mplus: Transition probabilities influenced by covariates. Mplus Web Notes, 13, 1-30. Retrieved from <http://www.statmodel.com/examples/LTAwebnote.pdf>

Perra, O. (2020). Latent transition analysis. *SAGE Research Methods: Foundations*. <https://doi.org/10.4135/9781526421036878157>

Ryoo, J. H., Wang, C., Swearer, S. M., Hull, M., & Shi, D. (2018). Longitudinal model building using latent transition analysis: An example using school bullying data. Frontiers in Psychology, 9, 675. <https://doi.org/10.3389/fpsyg.2018.00675>